|
首先聲明：本人大菜鳥一個，剛接觸AS3不久，許多理念還沒來得及灌輸，這些case都是從網(wǎng)上down的，但因為解說是英文的，不利我們學習，我就充當一個translater，順便可以讓自己鞏固一下知識。
水平有限，錯誤難免，歡迎大蝦小蝦，大鳥小鳥指正。
下面進入正題：
案例5：熟悉AS3的package，以及多個package之間的相互通信
說明：一個很簡單的demo，有4個按鈕，當鼠標劃過和移開時會呈現(xiàn)出不同的狀態(tài)，單擊后變成disabled，再點擊其他的按鈕時，之前disabled的按鈕恢復，被點擊的按鈕失效。
演示：http://www.live-my-life-with-yuyi.com/as3_cases/communicating/
準備工作：打開源文件communicating_final.fla，點擊屬性里的發(fā)布設置，點擊Actionscript3旁邊的設置，在最下面的classpath里，引入classes的文件夾的路徑，然后點擊確定，前期工作就準備完了。
代碼：
源文件里的代碼很簡單：
import todd.interactive.ButtonSet;
var buttons:ButtonSet = new ButtonSet();
buttons.addButtons([one_mc,two_mc,three_mc,four_mc]);
addChild(buttons);
導入ButtonSet類，實例化，然后調(diào)用里面的一個方法，最后將它放到舞臺上。
classes文件夾下面的todd->interactive文件夾里有兩個as文件，其中一個就是剛剛調(diào)用的ButtonSet，來看看ButtonSet的源碼：
package todd.interactive
{
//其實只需載入display和events就可以了，不過多載入幾個并不影響文件大小和效率
import flash.display.*;
import flash.events.*;
import flash.filters.*;
import flash.net.*;
import flash.geom.*;
import flash.ui.*;
import flash.utils.*;
import fl.transitions.*;
import fl.transitions.easing.*;
public class ButtonSet extends MovieClip
{
public var buttons:Array;
public function ButtonSet()
{
}
public function addButtons(buttonSet:Array):void
{
buttons = buttonSet;
for(var i:int = 0; i < buttons.length; i++)
{
addChild(buttons[i]);
}
}
}
}
一個類應該被放在一個package里面，就像錢應該被放到錢包里一樣。package后面定義的是該類的路徑。然后一系列常用的類。
定義了一個全局變量buttons，在變量前面加一個public就可以了。這樣就能在整個類中被訪問到。
類名應該和文件名一樣（區(qū)分大小寫），然后定義一個同名函數(shù)，這個函數(shù)會在類被初始化時調(diào)用，就像php4的類一樣。這里只是搭了個架子，沒有具體內(nèi)容。
然后定義了一個函數(shù)addButtons，它的作用就是將一些mc或者sprites放到自己的container里（addChild）。
還有一個類：DisablingButton，也是位于todd->interactive文件夾下，這也是這個案例的核心。對了，之前已經(jīng)將RectButton的linkage里的baseClass設置為todd.interactive.DisablingButton。
代碼稍微有點長，且聽我細細道來
package todd.interactive{
import flash.display.*;
import flash.events.*;
import todd.interactive.ButtonSet;
public class DisablingButton extends MovieClip {
var labels:Array;
var thisParent:*;
var thisIndex:int;
public function DisablingButton() {
labels = this.currentLabels;
this.addEventListener(MouseEvent.CLICK, disableButton);
this.addEventListener(MouseEvent.ROLL_OVER, over);
this.addEventListener(MouseEvent.ROLL_OUT, out);
this.addEventListener(Event.ADDED,setParent);
}
function disableButton(event:MouseEvent):void {
for (var i:int = 0; i < labels.length; i++) {
if (labels[i].name == "disable") {
this.gotoAndPlay("disable");
}
}
this.removeEventListener(MouseEvent.CLICK, disableButton);
this.removeEventListener(MouseEvent.ROLL_OVER, over);
this.removeEventListener(MouseEvent.ROLL_OUT, out);
enableOthers();
}
function enableButton():void {
this.addEventListener(MouseEvent.CLICK, disableButton);
this.addEventListener(MouseEvent.ROLL_OVER, over);
this.addEventListener(MouseEvent.ROLL_OUT, out);
this.gotoAndStop(1);
}
function over(event:MouseEvent):void {
for (var j:int = 0; j < labels.length; j++) {
if (labels[j].name == "over") {
this.gotoAndPlay("over");
}
}
}
function out(event:MouseEvent):void {
for (var k:int = 0; k < labels.length; k++) {
if (labels[k].name == "out") {
this.gotoAndPlay("out");
}
}
}
function setParent(event:Event):void {
if (this.parent is ButtonSet) {
thisParent=this.parent;
for (var w:int=0; w < thisParent.buttons.length; w++) {
if (this == thisParent.buttons[w]) {
thisIndex=w;
}
}
}
}
function enableOthers():void {
for (var z:int=0; z < thisParent.buttons.length; z++) {
if (z != thisIndex) {
thisParent.buttons[z].enableButton();
}
}
}
}
}
載入了兩個常用類后，又載入了剛剛定義的ButtonSet類，這樣我們就能使用ButtonSet的一些方法了。
注意：這個類必須繼承Movieclip類，因為該類的對象是一個mc。
然后定義了一些全局變量（默認均為public）。
創(chuàng)建析構函數(shù)DisablingButton，labels = this.currentLabels; 這句話的意思是取得當前mc的label屬性，以array的形式返回，包含了label.frame，label.name等等的屬性。
然后監(jiān)聽自己的鼠標點擊、移入、移出事件。
this.addEventListener(Event.ADDED,setParent);這句話的意思是當自己被添加進一個容器時調(diào)用setParent函數(shù)。
disableButton這個函數(shù)作用是，將當前mc的狀態(tài)變成disabled，然后取消監(jiān)聽事件，同時激活其他的按鈕。
enableButton函數(shù)的作用就是激活自己的監(jiān)聽事件，并初始化自己的狀態(tài)。
over和out函數(shù)很簡單，就是設置自己當前的狀態(tài)。
setParent函數(shù)的最終目的是捕獲點擊事件發(fā)生在哪個mc上（gotoAndPlay方法將觸發(fā)EVENT.ADDED，所以over和out函數(shù)都將觸發(fā)setParent函數(shù)，這也是一個待改進的地方）。
enableOthers函數(shù)顧名思義，激活其他的按鈕。因為setParent已經(jīng)記住了，最后的點擊事件發(fā)生在哪個mc上，所以只要遍歷一下buttons，然后激活其他的mc就可以了。
案例分析完畢。
源文件下載
經(jīng)典論壇討論：
http://bbs.blueidea.com/thread-2807809-1-1.html
本文鏈接：http://m.95time.cn/tech/multimedia/2007/5112.asp 
出處：藍色理想
責任編輯：tada
◎進入論壇RIA設計與應用版塊參加討論
|
